! Xyplex CCL   $RCSfile: MultiTech_MultiModem_1432BA,v $
!             $Revision: 1.2 $
!                 $Date: 1994/01/06 20:53:44 $
!
! "MultiTech MultiModem1432BA - 11/30/92"
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 57600, 0, 8, 1
!
! first recall the factory configuration, and set the modem in Hayes 
! extended response codes and turn off echo and baud adjust.
settries 0
matchclr
matchstr 1 3 "OK\13\10"
@LABEL 2
write "AT&F&Q1X4E0$BA0\13"
matchread 20
inctries
iftries 2 59
! Modem not responding, toggle DTR
DTRClear
pause 5
DTRSet
jump 2
!
! Next, turn ON CTS flow control, and disable MNP
!
@LABEL 3
matchstr 1 4 "OK\13\10"
write "AT&D3&E0&E4\13"
matchread 30
jump 59
!
! reduce transmit buffer size
!
@LABEL 4
matchstr 1 5 "OK"
write "AT&B1\13"
matchread 30
jump 59
!
! Assuming that the modem speaker is on, if str 2 is "0" turn it off
!
@LABEL 5
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59

!
! The modem is ready so enable answering, or originate a call
!
@LABEL 8
ifANSWER 30
note "Dialing ^1" 3
write "ATDT^1\13"
!
@LABEL 9
matchstr 1 11 "CONNECT 1200\13\10"
matchstr 2 12 "CONNECT 2400\13\10"
matchstr 3 13 "CONNECT 4800\13\10"
matchstr 4 19 "CONNECT 7200\13\10"
matchstr 5 14 "CONNECT 9600\13\10"
matchstr 6 20 "CONNECT 12000\13\10"
matchstr 7 18 "CONNECT 14400\13\10"
matchstr 8 50 "NO CARRIER\13\10"
matchstr 9 50 "ERROR\13\10"
matchstr 10 52 "NO DIALTONE\13\10"
matchstr 11 53 "BUSY\13\10"
matchstr 12 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 1200 bps." 2
serreset 57600, 0, 8, 1
!
jump 15
@LABEL 12
note "Communicating at 2400 bps." 2
serreset 57600, 0, 8, 1
jump 15
!
@LABEL 13
note "Communicating at 4800 bps." 2
serreset 57600, 0, 8, 1
jump 15
!
@LABEL 19
note "Communicating at 7200 bps." 2
serreset 57600, 0, 8, 1
jump 15
!
@LABEL 14
note "Communicating at 9600 bps." 2
serreset 57600, 0, 8, 1
jump 15
!
@LABEL 20
note "Communicating at 12000 bps." 2
serreset 57600, 0, 8, 1
jump 15
!
@LABEL 18
note "Communicating at 14400 bps." 2
serreset 57600, 0, 8, 1
@LABEL 15
HSRESET 0 1 0 0 0 0
ifANSWER 16
pause 30
@LABEL 16 
exit 0
!
! @ANSWER
! Set up the modem to answer
@LABEL 30
write "ATS0=1\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  13 "CONNECT 4800\13\10"
matchstr 5  19 "CONNECT 7200\13\10"
matchstr 6  14 "CONNECT 9600\13\10"
matchstr 7  20 "CONNECT 12000\13\10"
matchstr 8  18 "CONNECT 14400\13\10"
matchstr 9  50 "NO CARRIER\13\10"
matchstr 10 50 "ERROR\13\10"
matchstr 11 52 "NO DIALTONE\13\10"
matchstr 12 53 "BUSY\13\10"
matchstr 13 54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
matchclr
matchstr 1 62 "OK\13\10"
matchstr 2 62 "NO CARRIER\13\10"
matchstr 3 62 "ERROR\13\10"
write "ATH\13"
matchread 10
inctries
iftries 3 62
! no response, try escape sequence
DTRClear
pause 5
DTRSet
write "+++"
matchclr
matchstr 1 61 "OK\13\10"
matchread 15
jump 61
!
@LABEL 62
! set modem back to factory settings
pause 5
write "AT&F\13"
matchclr
matchstr 1 63 "OK\13\10"
matchread 30
!
@LABEL 63
exit 0
