|  | Home · All Namespaces · All Classes · Main Classes · Grouped Classes · Modules · Functions |

[Previous: qmake Tutorial] [Contents] [Next: Using qmake]

# qmake Common Projects

This chapter describes how to set up `qmake` project files for three common project types that are based on Qt. Although all kinds of projects use many of the same variables, each of them use project-specific variables to customize output files.

Platform-specific variables are not described here; we refer the reader to the Deploying Qt Applications document for information on issues such as building universal binaries for Mac OS X and handling Visual Studio manifest files.

- Building an Application

- The app Template

- Building a Library

- The lib Template

- Building a Plugin

- Building a Qt Designer Plugin

- Building and Installing in Debug and Release Modes

- Building in Both Modes
- Installing in Both Modes

## Building an Application

### The app Template

The `app` template tells `qmake` to generate a Makefile that will build an application. With this template, the type of application can be specified by adding one of the following options to the `CONFIG` variable definition:

Option | Description
--- | ---
windows | The application is a Windows GUI application.
console | `app` template only: the application is a Windows console application.

When using this template the following `qmake` system variables are recognized. You should use these in your .pro file to specify information about your application.

- HEADERS - A list of all the header files for the application.
- SOURCES - A list of all the source files for the application.
- FORMS - A list of all the .ui files (created using `Qt Designer`) for the application.
- LEXSOURCES - A list of all the lex source files for the application.
- YACCSOURCES - A list of all the yacc source files for the application.
- TARGET - Name of the executable for the application. This defaults to the name of the project file. (The extension, if any, is added automatically).
- DESTDIR - The directory in which the target executable is placed.
- DEFINES - A list of any additional pre-processor defines needed for the application.
- INCLUDEPATH - A list of any additional include paths needed for the application.
- DEPENDPATH - The dependency search path for the application.
- VPATH - The search path to find supplied files.
- DEF_FILE - Windows only: A .def file to be linked against for the application.
- RC_FILE - Windows only: A resource file for the application.
- RES_FILE - Windows only: A resource file to be linked against for the application.

You only need to use the system variables that you have values for, for instance, if you don't have any extra INCLUDEPATHs then you don't need to specify any, `qmake` will add in the default ones needed. For instance, an example project file might look like this:

     TEMPLATE = app
     DESTDIR  = c:/helloapp
     HEADERS += hello.h
     SOURCES += hello.cpp
     SOURCES += main.cpp
     DEFINES += QT_DLL
     CONFIG  += qt warn_on release

For items that are single valued, e.g. the template or the destination directory, we use "="; but for multi-valued items we use "+=" to add to the existing items of that type. Using "=" replaces the item's value with the new value, for example if we wrote `DEFINES=QT_DLL`, all other definitions would be deleted.

## Building a Library

### The lib Template

The `lib` template tells `qmake` to generate a Makefile that will build a library. When using this template, in addition to the system variables mentioned above for the `app` template the `VERSION` variable is supported. You should use these in your .pro file to specify information about the library.

When using the `lib` template, the following options can be added to the `CONFIG` variable to determine the type of library that is built:

Option | Description
--- | ---
dll | The library is a shared library (dll).
staticlib | The library is a static library.
plugin | The library is a plugin; this also enables the dll option.

- VERSION - The version number of the target library, for example, 2.3.1.

## Building a Plugin

Plugins are built using the `lib` template, as described in the previous section. This tells `qmake` to generate a Makefile for the project that will build a plugin in a suitable form for each platform, usually in the form of a library. As with ordinary libraries, the `VERSION` variable is used to specify information about the plugin.

- VERSION - The version number of the target library, for example, 2.3.1.

### Building a Qt Designer Plugin

Qt Designer plugins are built using a specific set of configuration settings that depend on the way Qt was configured for your system. For convenience, these settings can be enabled by adding `designer` to the project's `CONFIG` variable. For example:

     CONFIG      += designer plugin

See the Qt Designer examples for more examples of plugin-based projects.

## Building and Installing in Debug and Release Modes

Sometimes, it is necessary to build a project in both debug and release modes. Although the `CONFIG` variable can hold both `debug` and `release` options, the `debug` option overrides the `release` option.

### Building in Both Modes

To enable a project to be built in both modes, you must add the `debug_and_release` option to your project's `CONFIG` definition:

     CONFIG += debug_and_release

     CONFIG(debug, debug|release) {
         TARGET = debug_binary
     } else {
         TARGET = release_binary
     }

The scope in the above snippet modifies the build target in each mode to ensure that the resulting targets have different names. Providing different names for targets ensures that one will not overwrite the other.

When `qmake` processes the project file, it will generate a Makefile rule to allow the project to be built in both modes. This can be invoked in the following way:

     make all

The `build_all` option can be added to the `CONFIG` variable in the project file to ensure that the project is built in both modes by default:

     CONFIG += build_all

This allows the Makefile to be processed using the default rule:

     make

### Installing in Both Modes

The `build_all` option also ensures that both versions of the target will be installed when the installation rule is invoked:

     make install

It is possible to customize the names of the build targets depending on the target platform. For example, a library or plugin may be named using a different convention on Windows to the one used on Unix platforms:

     CONFIG(debug, debug|release) {
         mac: TARGET = $$join(TARGET,,,_debug)
         win32: TARGET = $$join(TARGET,,d)
     }

The default behavior in the above snippet is to modify the name used for the build target when building in debug mode. An `else` clause could be added to the scope to do the same for release mode; left as it is, the target name remains unmodified.

[Previous: qmake Tutorial] [Contents] [Next: Using qmake]