@echo off
rem -- this script tested on MS-NT v4

rem -- Handle targets, like a real UNIX makefile.
if X%1 == X       GOTO T_ALL
if X%1 == Xclean  GOTO T_CLEAN
if X%1 == Xdoc    GOTO T_DOC
if X%1 == Xdocs   GOTO T_DOC

echo I don't understand target  "%1"
goto T_DONE

:T_ALL
echo ----------------------------------------------------------
rem -- "-g:none" reduces class size by about 9%
@echo on
javac -g:none AnalogApplet.java -deprecation
@echo off
goto T_DONE


:T_CLEAN
rem -- The "2>NUL:" suppresses messages when files do no exist.
rem --  Option /q doesn't do it.
del 2>NUL: *.class
del 2>NUL: *~
if exist DOC  del DOC\*.html
if exist DOC  del DOC\stylesheet.css
if exist DOC  del DOC\package-list
goto T_DONE


:T_DOC
rem -- Clean all documentation (and style sheets) in .\DOC subdir.
if NOT exist DOC  mkdir DOC
javadoc -d doc -package -windowtitle "BL2000 A-D Control" AnalogApplet.java


:T_DONE
